在 Excel 中，計算乘法既可用Product函數又可用星號 *，但它們有區別，Product函數不但能把單個數值作為參數，并且還能把數組和引用單元格作為參數，例如要計算 A1 到 A6 的所有數值的乘積，不需要一個個寫，只需寫 A1:A6 即可；而用星號只能一個個寫。計算除法也有兩種方法，一種是用Product函數，另一種是用斜杠（/），它們的區別與計算乘法相同。

在乘除法計算過程中，通常會遇到用一個數乘或除表格的所有數，它們既用可Excel提供的功能即可實現，又可用Excel乘法公式或除法公式實現，它們的區別為：一個在原數據修改，另一個生成新數據。

一、Excel乘法函數Product函數的語法

1、表達式：PRODUCT(Number1, [Number2], ...)

中文表達式：PRODUCT(數字、數組、單元格或單元格區域1, [數字、數組、單元格或單元格區域2], ...)

2、說明：

A、Product函數最多只能有 255 個 Number。

B、如果邏輯值（True 和 False）直接作為Product函數的參數，計算時，True被轉為 1，False 被轉為 0；如果邏輯值是在數組或引用單元格中，它們將被忽略。

C、如果數組或引用單元格區域包含空格或文本，計算時，它們也被忽略。

二、Excel乘法函數Product函數的使用方法及實例

（一）兩列數字相乘的實例

1、假如要求營業額。雙擊 E2 單元格，把公式 =PRODUCT(C2,D2) 復制到 E2，按回車，返回 13425；選中 E2，把鼠標移到 E2 右下角的單元格填充柄上，鼠標變為加號（+）后，雙擊左鍵，則求出剩余的營業額；操作過程步驟，如圖1所示：

圖1

2、說明：乘法公式 =PRODUCT(C2,D2) 中，C2 和 D2 為引用單元格，意思是把 C2 和 D2 中的數字相乘。

（二）True 和 False 在引用單元格、數組和直接作為參數的不同取值實例

1、選中 B1 單元格，輸入公式 =PRODUCT(A1:A3)，按回車，返回 3；雙擊 B2，把公式 =PRODUCT({3,TRUE,FALSE}) 復制到 B2，按回車，也返回 3；再雙擊 B3，把公式 =PRODUCT({3,TRUE,FALSE}) 復制到 B3，并把兩個大括號去掉，按回車，返回 0；操作過程步驟，如圖2所示：

圖2

2、公式說明：

A、乘法公式 =PRODUCT(A1:A3) 和 =PRODUCT({3,TRUE,FALSE}) 都返回 3，說明邏輯值（True 和 False）在引用單元格和數組都被忽略。

B、乘法公式 =PRODUCT(3,TRUE,FALSE) 返回 0，說明 True 和 False 直接作為參數時，True 被轉為 1、False 被轉為 0。

（三）參數為引用單元格區域的實例

1、假如要求 A 和 B 兩列數字的乘積。雙擊 C1 單元格，把公式 =PRODUCT(A1:A5,B1:B5) 復制到 C1，按回車，返回 9.90 ；操作過程步驟，如圖3所示：

圖3

2、公式說明：

乘法公式 =PRODUCT(A1:A5,B1:B5) 把 A1:A5 和 B1:B5 中的所有數字相乘，即 A1 * A2 * A3 * A4 * A5 * B1 * B2 * B3 * B4 * B5。

三、Excel 用 * 計算乘法的實例

1、同樣以求營業額為例。選中 E2 單元格，輸入公式 =C2*D2，按回車，返回 13425；再次選中 E2，單擊 E2 的單元格填充柄，則返回剩余營業額；操作過程步驟，如圖4所示：

圖4

2、用 * 計算乘法時，不能這樣 =(C2:C7)*(D2:D7) 求兩列數字的乘積，這樣只能返回 C2 * D2 的乘積。

四、Excel除法的計算方法實例

在 Excel 中，沒有提供直接計算除法的函數，除法計算需要用乘法計算函數Product，另外還可以用斜杠（/）計算，以下是它們的計算方法。

（一）用Product函數計算的實例

雙擊 C1 單元格，把公式 =PRODUCT(A1/B1) 復制到 C1，按回車，返回 20.83；選中 C1，雙擊 C1 的單元格填充柄，則返回剩余的結果；操作過程步驟，如圖5所示：

圖5

（二）用斜杠（/）計算的實例

選中 C1 單元格，輸入公式 =A1/B1，按回車，返回 20.83；再次選中 C1，同樣用雙擊 C1 的單元格填充柄的方法求剩余數值相除的結果；操作過程步驟，如圖6所示：

圖6

提示：在默認情況下，Excel除法計算結果會保留多位小數，如果要保留兩位小數，可以按 Ctrl + 1（需要關閉中文輸入法），打開“設置單元格格式”窗口，選擇“數字”選項卡，再選擇左邊的“數值”，然后在右邊“小數位數”右邊輸入 2，單擊“確定”即可。

五、Excel用一個數字乘或除表格中的所有數

（一）用一個數字乘表格中的所有數

假如要給表格中所有銷量乘 0.2。選中 E2 單元格，輸入 0.2，單擊一下 E3，退出輸入狀態，再次選中 E2，按 Ctrl + C 復制；框選D2:D7，右鍵它們，在彈出的菜單中選擇“選擇性粘貼”，在打開的窗口中，選擇“運算”下的“乘”，單擊“確定”，則表格中所有銷量都乘了 0.2；操作過程步驟，如圖7所示：

圖7

（二）用一個數字除表格中的所有數

假如要求把表格中的全部銷量都除以 2。選中 E2，輸入 2，按回車， 退出輸入狀態，再選中 E2，按 Ctrl + C 復制；框選 D2:D7 并右鍵它們，然后選擇“選擇性粘貼”，在打開的窗口中，選擇“運算”下面的“除”，點擊“確定”，則 D 列全部銷量都除了 2；操作過程步驟，如圖8所示：

圖8

六、Excel乘法函數Product函數的擴展應用實例

（一）If + Product函數組合實現按條件提價

1、假如要給水果價格低于 5 元的提價 10%。雙擊 E2 單元格，把公式 =IF(C2<5,PRODUCT(C2,(1+10%)),C2) 復制到 E2，按回車，返回 5，由于 5 不滿足條件，因此未提價；再次選中 E2，用雙擊 E2 單元格填充柄的方法把剩余價格提價；操作過程步驟，如圖9所示：

圖9

2、公式 =IF(C2<5,PRODUCT(C2,(1+10%)),C2) 說明：

A、C2<5 是 If 的條件；如果條件成立，則用 PRODUCT(C2,(1+10%)) 提價 10%，即把 C2 中的數值 5 乘 (1+10%)；否則返回 C2；由于C2 為 5，不滿足條件，因此返回 5。

B、當公式在 C3 時，C3 < 5 成立，C3 為 3，因此返回 PRODUCT(C3,(1+10%)) 的計算結果，即返回 3.3；其它的以此類推。

3、如果僅要求返回所有提過價的價格，可以用這個公式 =PRODUCT(IF(C2<5,C2,0),1+10%)，演示如圖10所示：

圖10

（二）數組指數運算與引用單元格指數運算

1、數組指數運算；雙擊 B2 單元格，把公式 =PRODUCT({5,3}^{1,-1}) 復制到 B2，按回車，返回 1.666666667。引用單元格指數運算；雙擊 C2，把公式 =PRODUCT((A2:A3)^{1,-1}) 復制到 C2，按 Ctrl + Shift + 回車，返回 1.00；操作過程步驟，如圖11所示：

圖11

2、公式說明：

A、公式 =PRODUCT({5,3}^{1,-1}) 中，共有兩個數組，第一個為底數數組，第二個為指數數組；計算時，第一次從底數數組中取出 5、從指數數組中取出 1，即計算 5 的 1 次方，結果為 5；第二次從底數數組中取出 3、從指數數組取出 -1，即計算 3 的 -1 次方，也就是 1/3，結果為 0.333333333333333；最后把兩次計算的結果相乘，即 5 * 0.333333333333333 等于 1.666666667。

B、公式 =PRODUCT((A2:A3)^{1,-1}) 為數組公式，因此要按 Ctrl + Shift + 回車；A2:A3 以數組形式返回 A2 和 A3 中的數值，即{5;3}，則公式變為 =PRODUCT({5;3}^{1,-1})，與直接把數組 {5,3} 寫到公式中一樣，但計算方法不一樣，計算時，第一次從底數數組中取出 5，再從指數數組中取出 1 和 -1，然后計算 5 的 1 次方和 -1 次方，結果為 5 和 0.2；第二次從底數數組中取出 3，同樣再從指數數組中取出 1 和 -1，然后計算 3 的 1 次方和 -1 次方，結果為 3 和 0.333333333333333；則公式變為 =PRODUCT({5,0.2;3,0.333333333333333})，最后把數組中的所有元素相乘，結果為 1。