在 Excel 中，Trim函數(shù)用于去文本的前后空格和字符之間的空格，但在去字符之間的空格時，它不會把所有空格都去除，而是留下一個空格；如果要把字符之間的所有空格都去掉，需要用Substitute函數(shù)。

在 Excel 去空格時，常常會遇到一些頑固空格，用Trim函數(shù)或Clean函數(shù)都無法去除，此時需要用Substitute函數(shù)替換，如果用Substitute函數(shù)仍然無法去除，還需要與 Left、Right 與 Code 函數(shù)組合才能把空格去掉。另外，如果求和的數(shù)值帶空格將無法求得正確的結果，這種情況需要先用TRIM函數(shù)把空格去掉，然后再求和。

一、Excel Trim函數(shù)的語法

1、表達式：TRIM(Text)

2、說明：

Text 為要去空格的文本；Trim函數(shù)可把文本前后所有空格都去掉，但如果要去掉文字之間的空格，它不會把全部空格都去掉，而是還留下一個。

二、Excel Trim函數(shù)的使用方法及實例

（一）去掉文本前后所有空格的實例

假如要把文本“   Excel 函數(shù)教程    ”前后的所有空格都去掉。雙擊 A1 單元格，把公式 =TRIM("   Excel 函數(shù)教程    ") 復制到 A1，按回車，返回“Excel 函數(shù)教程”；當前單元格為左對齊，文字靠左邊，左邊的空格不見了；單擊“右對齊”圖標，文字靠右邊，右邊的空格也不見了；操作過程步驟，如圖1所示：

圖1

（二）去掉文字之間空格的實例

1、假如要把文本“Excel    函數(shù)    教程”中的空格去掉。雙擊 B1 單元格，輸入公式 =TRIM(A1)，按回車，返回“Excel 函數(shù) 教程”；雙擊 B2，把公式 =SUBSTITUTE(A1," ","") 復制到 B2，按回車，返回“Excel函數(shù)教程”；操作過程步驟，如圖2所示：

圖2

2、公式說明：

A、公式 =TRIM(A1) 沒有完全把“Excel    函數(shù)    教程”中的空格去掉，有空格之處都還留下一個空格。

B、公式 =SUBSTITUTE(A1," ","") 把“Excel    函數(shù)    教程”中所有空格都去除了；Substitute函數(shù)是一個替換字符函數(shù)，它在這里的意思是，用空文本 "" 把所有空格都替換掉。

三、Excel 頑固空格的去除方法（Trim函數(shù)不起作用的解決方法）

（一）去不除的空格能復制

1、雙擊 E2 單元格，輸入公式 =TRIM(A2)，按回車，A2 中的空格沒有被去掉；雙擊 E2，把 TRIM 改為 CLEAN，按回車，A2 中的空格仍然還在；再次雙擊 E2，把 CLEAN(A2) 改為 SUBSTITUTE(A2," ","")，按回車，A2 中的空格依然還在；雙擊 A2，用鼠標選中一個空格，按Ctrl + C 復制，再雙擊 E2，選中被替換空格 " "，按 Ctrl + V 粘貼，按回車，則 A2 中的空格被替換掉；操作過程步驟，如圖3所示：

圖3

2、公式說明：

A、公式 =TRIM(A2) 與 =CLEAN(A2) 都不能把 A2 中的空格去掉，說明該空格不是普通的按空格鍵所產生的空格和非打印字符空格；Clean函數(shù)用于去掉非打印字符。

B、公式 =SUBSTITUTE(A2," ","") 中的被替換字符 " " 為按空格鍵輸入時，不能替換 A2 中的空格，只有把 A2 中的空格復制到被替換字符中，才能把 A2 中的空格都替換。

提示：如果遇到用Substitute函數(shù)仍然不能把空格去除，可以按 Ctrl + H 打開“查找替換”窗口，把不能替換的字符復制到“查找內容”右邊的輸入框中，單擊“全部替換”就能去除了。

（二）去不掉的空格不能復制

1、先查看空格的 ASCII 碼；雙擊 B1 單元格，把公式 =CODE(LEFT(A1)) 復制到 B1，按回車，返回 63。然后用返回空格的 ASCII 碼 63 作為條件把空格替換掉；雙擊 B2，把公式 =SUBSTITUTE(A1,IF(CODE(LEFT(A1))=63,LEFT(A1)),"") 復制到 B2，按回車，A1 中文本前面的所有空格都被去掉，A1 已經設置為居中對齊，文本因左邊有空格而未居中，而 B2 中的文本已經居中，說明空格被去掉；操作過程步驟，如圖4所示：

圖4

2、公式說明：

A、公式 =CODE(LEFT(A1)) 中，LEFT(A1) 用于從 A1 的文本左邊截取一個字符，然后用Code函數(shù)返回所截取字符的 ASCII 碼，結果為 63。

B、公式 =SUBSTITUTE(A1,IF(CODE(LEFT(A1))=63,LEFT(A1)),"") 中，IF(CODE(LEFT(A1))=63,LEFT(A1)) 用于返回一個去不掉的空格，意思是：如果截取 A1 的文本左邊一個空格，該空格的 ASCII 碼等于 63，則返回該空格；CODE(LEFT(A1))=63 為 If 的條件，63 是在 B1 單元格中求出空格的 ASCII 碼；最后用空文本（""）替換 A1 中所有 ASCII 碼為 63 的空格。

四、Excel Trim函數(shù)的擴展應用實例

（一）Left + Trim函數(shù)組合實現(xiàn)先去掉空格再截取

1、假如要把 A 列中的數(shù)字截取出來。雙擊 B1 單元格，把公式 =LEFT(A1,3) 復制到 B1，按回車，返回空文本；雙擊 B1，給 A1 加上Trim()，按回車，返回 2.5；選中 B1，把鼠標移到 B1 右下角的單元格填充柄上，鼠標變?yōu)榧犹柡螅�雙擊左鍵，則截取出剩余單元格的數(shù)字；操作過程步驟，如圖5所示：

圖5

2、公式 =LEFT(TRIM(A1),3) 說明：

A、TRIM(A1) 用于去掉 A1 中“   2.5升/瓶”左邊的空格，它返回“2.5升/瓶”。

B、則公式變?yōu)?=LEFT("2.5升/瓶",3)，最后用 Left 從左邊第一個字符開始截取 3 個字符，恰好截得數(shù)字。

（二）Sum + Trim函數(shù)組合實現(xiàn)數(shù)值帶空格的求和

1、假如要求銷量之和，銷量列中的數(shù)值為文本且前面帶空格。雙擊 D9 單元格，輸入公式 =SUM(D2:D8)，按回車，返回 0；雙擊 D9，給D2:D8 加上 TRIM()，按 Ctrl + Shift + 回車，仍然返回 0；再次雙擊 D9，在 TRIM 前加 --，按 Ctrl + Shift + 回車，返回求和結果5336；操作過程步驟，如圖6所示：

圖6

2、公式 =SUM(--TRIM(D2:D8)) 說明：

A、公式 =SUM(--TRIM(D2:D8)) 為數(shù)組公式，因此需要按 Ctrl + Shift + 回車；D2:D8 以數(shù)組返回 D2 至 D8 中的全部數(shù)值。

B、則 TRIM(D2:D8) 變?yōu)?TRIM({" 569";" 638";" 897";" 528";" 830";" 982";" 892"})，接著，第一次從數(shù)組中取出第一個元素 "569"，把它的空格去掉；第二次從數(shù)組中取出第二個元素 " 638"，再把它的空格去掉；其它的以此類推，最后返回{"569";"638";"897";"528";"830";"982";"892"}。

C、則公式變?yōu)?=SUM(--{"569";"638";"897";"528";"830";"982";"892"})，進一步計算，把數(shù)組中的每個元素由字符型轉為數(shù)值型，--用于把字符轉為數(shù)值，它相當于Value函數(shù)。

D、則公式進一步變?yōu)?=SUM({569;638;897;528;830;982;892})，最后用 Sum 對數(shù)組中的所有元素求和。

提示：由于 D2:D8 中的數(shù)字為文本型，當在把公式復制到 D9 按回車后，如果再次雙擊 D9，此時會顯示公式，按回車，不能再求和，因為 D9 的格式自動變?yōu)?ldquo;文本”，要解決此問題，需要把 D9 的格式設置為“數(shù)值”，方法為：按 Ctrl + 1（需關閉中文輸入法），打開“設置單元格格式”窗口，選擇“數(shù)字”選項卡，再選擇左邊“數(shù)值”，如果不想保留小數(shù)位數(shù)，把“小數(shù)位數(shù)”設置為 0，最后單擊“確定”即可。