在 Excel 中，Len函數和LenB函數都用于返回指定文本的長度。Len函數返回字符數，它把全角（如“漢字”）和半角（如“數字和字母”）字符都計作一個字符；LenB函數返回字節數，它把全角字符計作 2 個字節、半角字符計作 1 個字節。

Len函數和LenB函數常與 Left、Mid、Right、Substitute 等函數組合使用，例如 Left + Len + LenB 組合實現截取字符串左邊的數字或字母，Right + Len + LenB 組合實現截取字符串右邊的漢字，Len + Substitute 組合實現統計一個單元格中的文本指定詞組的個數。

一、Excel Len函數和LenB函數的語法

1、 Len函數表達式：LEN(Text)

中文表達式：LEN(文本)

2、 LenB函數表達式：LENB(Text)

中文表達式：LENB(文本)

3、說明：

A、Len函數和LenB函數都返回指定文本的長度，但它們有區別：Len函數返回指定文本的字符數，它將每個半角字符（如“數字或字母”）和全角字符（如“漢字”）都計作一個字節；LenB函數返回指定文本的字節數，它將半角字符計作一個字節、全角字符計作兩個字節。

B、Len函數和LenB函數將空格也計作字符進行統計，但空文本（如 ""），它們都忽略。

二、Excel Len函數的使用方法及實例

（一）返回空格和空文本的長度實例

1、雙擊 A1 單元格，輸入公式 =LEN(" ")，按回車，返回 1；雙擊 A1，把雙引號之間的空格刪除，按回車，返回 0；再次雙擊 A1，把雙引號 "" 改為 B1，按回車，同樣返回 0；操作過程步驟，如圖1所示：

圖1

2、公式說明：

A、公式 =LEN(" ") 返回空格 " " 的長度，結果為 1，說明Len函數將空格的長度計為 1。

B、公式 =LEN("") 和 =LEN(B1) 返回空文本 "" 和空單元格的長度，結果為 0，說明Len函數忽略空文本和空單元的長度。

（二）返回半角和全角字符的長度實例

1、雙擊 B1 單元格，輸入公式 =LEN(A1)，按回車，返回 15；操作過程步驟，如圖2所示：

圖2

2、公式說明：

公式 =LEN(A1) 返回 A1 中文本的長度，A1 的文本由半角字符（即“空格、字母和數字”）和全角字符（即“漢字”）組成，它們加起來共 15 個，說明Len函數把半角和全角字符都計作一個字符。

三、Excel LenB函數的使用方法及實例

（一）返回星號 * 和問號 ? 的長度實例

1、雙擊 B1 單元格，把公式 =LENB(A1) 復制到 B1，按回車，返回 5；操作過程步驟，如圖3所示：

圖3

2、A1 中有兩個星號 * 與 兩個問號 ?，星號是不區分半角與全角的，問號區分半角與全角，因此“*?*？”的長度為 5。

（二）返回全角字符與半角字符的長度實例

1、雙擊 B1 單元格，把公式 =LENB(A1) 復制到 B1，按回車，返回 10；雙擊 B2，輸入公式 =LENB(A2)，按回車，返回 19；操作過程步驟，如圖4所示：

圖4

2、A1 中的 Excel 2016 有 5 個字母、4 個數字和 1 個空格，加起來共 10 個；A2 中除有 A1 的內容外，還有 1 個空格和 4 個漢字，長度為 19，說明每個漢字，LenB函數計作 2 個字節，數字、字母和空格計作一個字節。

四、Excel Len函數和LenB函數的應用實例

（一）Left + Len + LenB函數組合實現截取文本中的字母和數字

1、假如要截取“Excel 2016 函數教程”中的字母和數字。雙擊 B2 單元格，把公式 =LEFT(A2,LEN(A2)-(LENB(A2)-LEN(A2))-1) 復制到 B2，按回車，返回“Excel 2016”；操作過程步驟，如圖5所示：

圖5

2、公式 =LEFT(A2,LEN(A2)-(LENB(A2)-LEN(A2))-1) 說明：

A、LEN(A2) 用于返回 A2 的字符個數，結果為 15；LENB(A2) 用于返回 A2 的字節個數，結果為 19。

B、(LENB(A2)-LEN(A2)) 用于計算有多少個漢字，用字節數 19 減字符數 15 的結果 4 恰好是漢字總數；這是利用了LenB函數把每個漢字計作兩個字節，Len函數把所有字符計作一個字符。

C、LEN(A2)-(LENB(A2)-LEN(A2))-1 用于計算要截取字符串的長度，用總字符數 15 減掉 4 個漢字，結果恰好剩下字母、數字和空格數，減 1 是把 2016 后的空格去掉。

D、則公式變為 =LEFT(A2,10)，最后用Left函數從 A2 中左邊第一個字符開始截取，共截取 10 字符，恰好截取得 Excel 2016。

（二）Right + Len + LenB函數組合實現截取漢字

1、同樣以截取“Excel 2016 函數教程”的漢字為例。雙擊 B2 單元格，把公式 =RIGHT(A2,LENB(A2)-LEN(A2)) 復制到 B2，按回車，返回“函數教程”；操作過程步驟，如圖6所示：

圖6

2、公式 =RIGHT(A2,LENB(A2)-LEN(A2)) 說明：

A、LENB(A2)-LEN(A2) 用于計算 A2 中的漢字個數（上面已經解釋過），結果為 4。

B、則公式變為 =RIGHT(A2,4)，最后用 Right 函數從右邊開始截取 4 個字符，結果恰好為四個漢字“函數教程”。

提示：以上截取數字、字母和漢字的方法只適用于數字和字母在左邊、漢字在右邊的情況，如果數字或字母分布在漢字兩邊（如“Excel 函數教程 2016”）將不能正確截取，此時，需用 Left + LookUp + LenB + Mid + Row 函數實現，具體請參考《Excel拆分單元格與用分列與公式把一列內容拆分為兩列或三列》一文。

（三）Len + Subtitute函數組合實現返回文本中指定詞組的個數

1、假如要統計一個單元格中某個詞（如 excel）的個數。雙擊 A2 單元格，把公式 =(LEN(A1)-LEN(SUBSTITUTE(A1,"excel","")))/LEN("excel") 復制到 A2，按回車，返回 3；雙擊 A1，把 E 改 e，A2 中的值變為 4；操作過程步驟，如圖7所示：

圖7

2、公式 =(LEN(A1)-LEN(SUBSTITUTE(A1,"excel","")))/LEN("excel") 說明：

A、SUBSTITUTE(A1,"excel","") 用于用空值 "" 取代 A1 中所有 excel；LEN(SUBSTITUTE(A1,"excel","")) 用于返回 A1 中除全部excel 外字符串的長度，結果為 28。

B、LEN(A1) 用于返回 A1 的長度 43，則 LEN(A1)-LEN(SUBSTITUTE(A1,"excel","")) 變為 43 - 28，結果等于 15，也就是 A1 中所有excel 的全部字母的個數。

C、LEN("excel") 用于返回 excel 的字母個數 5，則公式變為 15/5，結果等于 3；值得注意的是，Substitute函數區分大小寫，以大寫E 開頭的 Excel 并沒有被取代，結果才統計出 3 個 excel，當把 E 改為 e 后，才統計出 4 個。

（四）LenB函數把每個漢字的長度計為1的問題

1、如果 Excel 的默認語言沒有設置為“中文”，LenB函數把每個漢字的長度計為 1，要解決此問題，只需把 Excel 的默認語言設置為“中文”；演示如圖8所示：

圖8

2、把默認語言設置為“中文”后，一定要關閉所有打開的 Excel 窗口，然后重新打開，設置才生效。

（五）Len + if函數組合實現截取指定位數的數字

1、如果要求兩位數字截取一位、四位截取兩位、六位截取四位。雙擊 B1 單元格，把公式 =IF(LEN(A1)=2,LEFT(A1,1),IF(LEN(A1)=4,LEFT(A1,2),IF(LEN(A1)=6,LEFT(A1,4)))) 復制到 B1，按回車，返回 1；選中 B1，雙擊 B1 右下角的單元格填充柄，則返回剩余數字的截取結果；操作過程步驟，如圖9所示：

圖9

2、公式 =IF(LEN(A1)=2,LEFT(A1,1),IF(LEN(A1)=4,LEFT(A1,2),IF(LEN(A1)=6,LEFT(A1,4)))) 說明：

A、LEN(A1) 返回 A1 中數字的長度；LEN(A1)=2 是左起第一個 IF 條件，如果 LEN(A1) 等于 2，則執行 LEFT(A1,1)，即用 Left 函數從左邊截取一個數字；否則執行 IF(LEN(A1)=4,LEFT(A1,2),IF(LEN(A1)=6,LEFT(A1,4))。

B、繼續往下執行，如果 LEN(A1)=4 成立，執行 LEFT(A1,2)，即用 Left 函數從左邊截取兩位數字；否則執行 IF(LEN(A1)=6,LEFT(A1,4)；最后一個 If 以此類推。

（六）Right + Len + Find函數組合實現從右邊截取指定字符

1、如果要截取右邊兩個單詞。雙擊 B1 單元格，把公式 =RIGHT(A1,LEN(A1)-FIND("fun",A1)+1) 復制到 B1，按回車，返回 function tutolail；操作過程步驟，如圖10所示：

圖10

2、公式 =RIGHT(A1,LEN(A1)-FIND("fun",A1)+1) 說明：

A、FIND("fun",A1) 用于返回要截取字符（function tutolail）的開始位置，結果為 12。

B、LEN(A1) 用于返回 A1 中文本的長度，結果為 28。LEN(A1)-FIND("fun",A1)+1 用于計算要截取字符的長度，結果為 28 - 12 + 1 = 17。

C、則公式變為 =RIGHT(A1,17)，最后用 Right 函數從右邊截取 17 個字符，恰好是 function tutolail。