在 Excel 中，Find函數用于查找指定文本在查找文本的文本中的位置，FindB函數與Find函數功能一樣，只是Find函數把全角字符（如漢字）和半角字符（如數字和字母）都算一個字符，而FindB函數以字節計，把全角字符計作兩個字節、半角字符計作一個字節。

在日常應用中，Find函數和FindB函數常與 If、Sum、Mid、Left、IsNumber 等函數組合使用，如 Mid + Find（或 FindB）組合實現從任意指定字符開始截取字符，If + IsNumber + Find 組合實現動態查找，Sum + IsNumber + Find 組合實現一次查找多個值。

一、Excel Find函數和FindB函數的語法

1、Find函數表達式：FIND(Find_Text, Within_Text, [Start_Num])

中文表達式：FIND(查找文本, 要查找文本的文本, [查找開始位置])

2、FindB函數表達式：FINDB(Find_Text, Within_Text, [Start_Num])

中文表達式：FINDB(查找文本, 要查找文本的文本, [查找開始位置])

3、說明：

A、Find函數將全角字符（如漢字）和半角字符（如數字與字母）都計作一個字符，FindB函數將全角字符計作兩個字節、半角字符計作一個字節。Find函數和FindB函數都區分大小寫，并且不允許使用通配符；如果要求忽略大小寫與允許使用通配符，只能使用Search函數或SearchB函數。

B、如果 Find_Text 為空文本 ("")，默認返回第一個字符的位置 1；Find_Text 不能包含任何通配符，如問號（?）或星號（*）。

C、Start_Num 為可選項，若省略，則默認從第一個字符開始查找；Start_Num 小于等于 0 或大于等于 Within_Text 的長度，Find 與 FindB 都返回值錯誤 #VALUE!。

D、若在 Within_Text 中沒有找到查找文本，也返回值錯誤 #VALUE!。

二、Excel Find函數的使用方法及實例

（一）查找短文本省略查找開始位置的實例

1、假如要查找 Kg 在“2685kg”中位置。雙擊 E2 單元格，把公式 =FIND("kg",D2) 復制到 E2，按回車，返回 5；再次雙擊 E2，在 D2 后輸入逗號，按回車，返回值錯誤 #VALUE!；操作過程步驟，如圖1所示：

圖1

2、公式 =FIND("kg",D2) 中，"kg" 為查找文本，D2 為要查找文本的文本，公式省略了最后一個參數“查找開始位置”，則默認從第一個字會開始查找。另外，公式 =FIND("kg",D2,) 返回值錯誤，說明省略“查找開始位置參數”時，不能在第二個參數后加逗號。

（二）區分大小寫與不允許使用通配符的實例

1、假如要查找“Excel 教程”中的大小寫 e。雙擊 B1 單元格，把公式 =FIND("E",A1) 復制到 B1，按回車，返回 1；雙擊 B2，把公式 =FIND("E",A1) 復制到 B2 后，把大寫 E 改為小寫 e，按回車，返回 4；再次雙擊 B2，在 e 后輸入 *，按回車，返回值錯誤 #VALUE!；操作過程步驟，如圖2所示：

圖2

2、公式說明：

A、=FIND("E",A1) 返回大寫 E 的位置 1，而公式 =FIND("e",A1) 返回小寫 e 的位置 4，說明Find函數區分大小寫，否則兩個公式都返回 1。

B、公式 =FIND("e*",A1) 的查找文本 "e*" 含有通配符 *，它返回值錯誤 #VALUE!，說明Find函數不能使用通配符。

（三）查找文本為空（""）和空格（" "）的實例

1、雙擊 B1 單元格，把公式 =FIND("",A1) 復制到 B1，按回車，返回 1；雙擊 B1，把 "" 改為 " "，按回車，返回 6；操作過程步驟，如圖3所示：

圖3

2、公式 =FIND("",A1) 查找空（""），Find函數默認返回第一個字符的位置 1；公式 =FIND(" ",A1) 查找空格，返回“Excel 教程”中空格的位置 6。

（四）返回值錯誤 #VALUE! 的實例

1、雙擊 B1 單元格，把公式 =FIND("c",A1,0) 復制到 B1，按回車，返回值錯誤 #VALUE!；再次雙擊 B1，把 0 改為 8，按回車，也返回 值錯誤 #VALUE!；操作過程步驟，如圖4所示：

圖4

2、公式說明：

A、公式 =FIND("c",A1,0) 的查找開始位置為 0，但返回錯誤，說明Find函數的查找起始位置從 1 開始。

B、公式 =FIND("c",A1,8) 的查找起始位置為 8，而 A1 中的“Excel 教程”，只有 8 個字符，公式從第 8 個位置開始是查找第 9 個字符及之后的字符，因此返回錯誤。

（五）找不到查找文本返回錯誤及處理方法實例

1、雙擊 B1 單元格，把公式 =FIND("a",A1,1) 復制到 B1，按回車，返回值錯誤 #VALUE!；再次雙擊 B1，把公式改為 =IFERROR(FIND("a",A1,1),0)，按回車，返回 0；操作過程步驟，如圖5所示：

圖5

2、公式說明：

A、公式 =FIND("a",A1,1) 要在“Excel 教程”中從第一個字符開始查找 a，但沒有找到，因此返回錯誤。

B、公式 =IFERROR(FIND("a",A1,1),0) 中，IfError函數是錯誤判斷函數，意思是：如果 FIND("a",A1,1) 返回正確的位置，則 IfError 返回該值，否則返回 0。

三、Excel FindB函數的使用方法及實例

（一）在由數字和字母組成的字符串中查找的實例

1、雙擊 B1 單元格，把公式 =FINDB("0",A1,6) 復制到 B1，按回車，返回 8；操作過程步驟，如圖6所示：

圖6

2、公式 =FINDB("0",A1,6) 中，0 為查找文本，A1 為查找 0 的文本，6 為查找開始位置；公式的意思是：從 A1 中的“Excel 2016”中的第 6 個字符開始查找 0，返回 0 的位置為 8；從返回位置可知，FindB函數與Find函數一樣，都把數字和字母計作一個字節。

（二）在由數字、字母和漢字組成的字符串中查找的實例

1、雙擊 B1 單元格，把公式 =FINDB("16",A1) 復制到 B1，按回車，返回 14；操作過程步驟，如圖7所示：

圖7

2、公式 =FINDB("16",A1) 在 A1 的“Excel 教程 2016”中查找 16，返回結果為 14，它正是 1 的位置；1 的前面共有 5 個字母、2 個空格、2 個數字和 2 個漢字，它們加起來為 11，說明 FindB 把每個漢字計作兩個字節。

四、Excel Find函數和FindB函數的應用實例

（一）Mid + Find函數組合實現從任意指定字符開始截取字符串

1、假如要截取“WS-560長袖白襯衫86.9”中的漢字。雙擊 B1 單元格，把公式 =MID(A1,FIND("長",A1),5) 復制到 B1，按回車，返回“長袖白襯衫”；操作過程步驟，如圖8所示：

圖8

2、公式 =MID(A1,FIND("長",A1),5) 說明：

A、FIND("長",A1) 用于在 A1 中查找“長”的位置，結果為 7；在比較長的字符串中截取時，通常用Find函數確定要截取字符串的開始位置，這樣能快速找出查找起始位置，不用一個個去數。

B、則公式變為 =MID(A1,7,5)，A1 為要截取文本的文本，7 為開始截取位置，5 為截取長度，意思是：從第 7 個字符開始截取 5 字符，恰好截取得 A1 中的 5 個漢字。

提示：Mid + FindB 或 MidB + FindB 也可以實現同樣功能，公式可以分別這樣寫：=MID(A1,FINDB("長",A1),5) 或 =MIDB(A1,FINDB("長",A1),10)；后一個公式之所以寫 10，是因為用 MidB 截取時，每個漢字占兩個字節。

（二）If + IsNumber + Find函數組合實現在動態查找

1、假如要求標出 A 列是否包含 B 列的年份，如果包含標出“是”，否則標出“否”。雙擊 C2 單元格，把公式 =IF(ISNUMBER(FIND(B2,A2)),"是","否") 復制到 C2，按回車，返回“是”；選中 C2，把鼠標移到 C2 右下角的單元格填充柄上，鼠標變為加號后，雙擊左鍵，則標出剩余行的相應結果；操作過程步驟，如圖9所示：

圖9

2、公式 =IF(ISNUMBER(FIND(B2,A2)),"是","否") 說明：

A、FIND(B2,A2) 用于在 A2 中查找 B2，如果找到，返回 B2 在 A2 中的位置，否則返回值錯誤 #VALUE!；當公式在 C2，返回 B2 在 A2 中的位置為 2。

B、則 ISNUMBER(FIND(B2,A2) 變為 ISNUMBER(2)，由于 2 為數字，所以 IsNumber 返回“真”。則公式變為 =IF(TRUE,"是","否")，If 的條件為真，所以返回“是”。

C、當公式在 C3 時，A2 與 B2 都自動變為 A3 和 B3（相當于往下拖），FIND(B3,A3) 返回值錯誤 #VALUE!，因為在 A3 中沒有找到 B3；ISNUMBER(#VALUE!) 返回“假”，則公式變為 =IF(FALSE,"是","否")，If 的條件為假，所以返回“否”。

（三）Sum + IsNumber + Find函數組合實現一次查找多個值

1、假如要一次查找 4 個值。雙擊 B1 單元格，把公式 =SUM(ISNUMBER(FIND({"S","襯衫",8,10},A1))*1) 復制到 B1，按回車，返回查找結果 3；操作過程步驟，如圖10所示：

圖10

2、公式 =SUM(ISNUMBER(FIND({"S","襯衫",8,10},A1))*1) 說明：

A、FIND({"S","襯衫",8,10},A1) 的找查找文本為一個數組，數組中共包含四個元素，也就是要在 A1 中查找四個值；執行時，第一次取出數組中的第一個元素 S，然后在 A1 中查找，返回結果為 2；第二次取出數組中的第二個元素 “襯衫”，同樣在 A1 中查找，結果為 10；其它的以此類推，最后返回數組 {2,10,12,#VALUE!}，由于在 A1 中找不到 10，所以返回 #VALUE!。

B、則公式變為 =SUM(ISNUMBER({2,10,12,#VALUE!})*1)，進一步計算用 IsNumber 判斷數組中的元素是否為數字，如果是數字，返回 True，否則返回 False，則公式變為 =SUM({TRUE,TRUE,TRUE,FALSE}*1)，再用數組中的每個元素與 1 相乘，相乘時，True 轉為 1、False 轉為 0，則公式變為 =SUM({1,1,1,0})，最后用 Sum 對數組中的每個元素求和，結果為 3。