在 Excel 中，Count函數用于統計數值與日期個數，它至少要包含一個值最多只能有 255 個值。Count函數不統計空格與不能轉為數字的文本，如果要統計它們需要用CountA函數。

　　Count函數除單獨使用外，還常與 If、Find 與 Frequency 函數組合使用；Count + If 組合實現統計滿足指定條件的個數，Count + Find 組合實現統計重復值的個數，Count + Frequency 組合實現統計不包括重復值（即唯一值）的個數。

　　一、Excel Count函數的語法

　　1、表達式：COUNT(Value1, [Value2], ...)

　　中文表達式：Count(值1, [值2], ...)

　　2、說明：

　　A、Value 可以是數字、數組或單元格區域的引用，至少要包含一個 Value，最多只能有 255 個。

　　B、如果 Value 為數字、日期、能轉為數值的文本（如"2"），都被計入統計個數。如果 Value 為邏輯值（True 或 False），若 Value 直接寫在Count函數中，則被計入統計個數；若 Value 為單元格或數組中的值，則不被計入統計個數。如果要統計有文本、邏輯值、空值（如公式返回的空值""）和錯誤值的單元格，可以用CountA函數。

　　C、如果 Value 為空格、不能轉為數值的文本（如"二"）或錯誤值，將不被計入統計個數。

　　二、Excel Count函數的使用方法及實例

　　（一）引用區域為單元格的實例

　　假如要統計 C 列的數字個數。雙擊 C8 單元格，輸入公式 =count(c2:c7)，按回車，返回統計結果 6；操作過程步驟，如圖1所示：

圖1

　　（二）統計數組中數值的實例

　　1、雙擊 A1 單元格，把公式 =COUNT(6,{3,8,10,5,2}) 復制到 A1，按回車，返回統計結果 6；操作過程步驟，如圖2所示：

圖2

　　2、公式 =COUNT(6,{3,8,10,5,2}) 的參數為一個數字和一個數組，統計結果為 6，說明獨立數字和數組都計入統計。

　　（三）Value 為數字、日期或能轉為數值的文本實例

　　1、雙擊 B1 單元格，輸入公式 =COUNT(A1:A3)，按回車，返回統計結果 2，把 A3 中 "16" 刪除，B1 中的值仍為 2；雙擊 B2，把公式=COUNT(38,2018/12/24,"16") 復制 B2，按回車，返回統計結果 3；操作過程步驟，如圖3所示：

圖3

　　2、三個相同的值，一個公式統計結果為 2，另一個公式統計結果為 3，它們之間的區別是一個值在單元格中，另一個值在數組中，并且從操作可以看出，單元格中的 "16" 沒有被統計，而數組中的 "16" 被統計了；這就說明數組中的 "16" 是能轉為數值的文本，而單元格中的"16" 不能，單元格中的能轉為數值的文本是指單元格格式為文本型。

　　（四）Value 含有邏輯值 True 和 False 的實例

　　1、雙擊 B1 單元格，輸入公式 =COUNT(A1:A3)，按回車，返回統計結果 1；雙擊 B2，把公式 =COUNT(38,TRUE,FALSE) 復制到 B2，按回車，返回統計結果 3；操作過程步驟，如圖4所示：

圖4

　　2、兩個公式也是統計一樣的值，一個返回 1，另一個返回 3，說明邏輯值在單元格時，Count函數不把它們計入統計個數，而在數組時把它們計入統計個數。

　　（五）Value 為空單元格、空值和錯誤值的實例

　　1、雙擊 B1 單元格，把公式 =COUNT(A1:A4) 復制到 B1，按回車，返回統計結果 0；雙擊 A1，里面什么都沒有，說明它為空單元格；再雙擊 A2，里面有一個返回空值 If 公式，說明空值也被Count函數忽略；操作過程步驟，如圖5所示：

圖5

　　2、從操作中可以看出，Count函數忽略空單元格、空值和錯誤值。

　　三、Excel Count函數的擴展使用實例

　　（一）If + Count函數組合統計滿足指定條件的個數

　　1、假如要統計銷量大于 2000 的水果銷量個數。雙擊 D8 單元格，把公式 =COUNT(IF(D2:D7>2000,D2:D7,"")) 復制到 D8，按回車，返回統計結果 3；操作過程步驟，如圖6所示：

圖6

　　2、公式 =COUNT(IF(D2:D7>2000,D2:D7,"")) 說明：

　　A、公式為數組公式，因此要按 Ctrl + Shift + 回車。

　　B、D2:D7>2000 為 If 的條件，D2:D7 以數組的形式返回 D2 至 D7 中的值，然后逐一取出每個元素與 2000 比較，如果大于 2000 返回 True，否則返回 False；例如：第一次取出 685，由于不大于 2000，所以返回 False；第二次取出 3500，由于大于 2000，所以返回 True，其它的以此類推；最后返回 {FALSE;TRUE;FALSE;TRUE;FALSE;TRUE}。

　　C、則 IF(D2:D7>2000,D2:D7,"") 變為 IF({FALSE;TRUE;FALSE;TRUE;FALSE;TRUE},D2:D7,"")，接著，取數組中的第一個元素 FALSE，由于為假，所以返回 ""；第二次取出數組的第二個元素 TRUE，由于為真，所以返回 D2:D7 與數組對應的元素 D3；其它的以此類推；最后返回{"";3500;"";2050;"";2200}。

　　D、則公式變為 =COUNT({"";3500;"";2050;"";2200})，最后用 Count 統計數組中數值的個數，因此結果為 3。

　　（二）Count + Find函數組合統計重復值的個數

　　1、假如要統計水果表中“分類”列“漿果”的個數。雙擊 B8 單元格，把公式 =COUNT(FIND("漿果",B2:B7)) 復制到 B8，按 Ctrl + Shift + 回車，返回統計結果 3，操作過程步驟，如圖7所示：

圖7

　　2、公式 =COUNT(FIND("漿果",B2:B7)) 說明：

　　A、FIND("漿果",B2:B7) 用于在 B2:B7 中找出所有“漿果”，如果為“漿果”返回 1，否則返回值錯誤 #VALUE!，最后返回數組{1;#VALUE!;1;#VALUE!;1;#VALUE!}。

　　B、則公式變為 =COUNT({1;#VALUE!;1;#VALUE!;1;#VALUE!})，最后對數組進行統計，由于錯誤值不統計，只統計數值，因此統計結果為 3。

　　（三）Count + Frequency函數組合統計不重復的數值個數

　　1、假如要統計價格不包含重復的個數。雙擊 C8 單元格，把公式 =COUNT(0/(FREQUENCY(C2:C7,C2:C7))) 復制到 C8，按回車，返回統計結果 5，操作過程步驟，如圖8所示：

圖8

　　2、公式 =COUNT(0/(FREQUENCY(C2:C7,C2:C7))) 說明：

　　A、FREQUENCY(C2:C7,C2:C7) 用于統計 C2:C7 每個數值的出現頻率；執行時，第一次取出第二個參數中的 C2（即 5），然后在 C2:C7 中統計小于等于 5 且大于 3.5 的數值個數（結果為 2），因為直接把 C2:C7 作為 Frequency函數的 Bins_Array 參數（即對要統計的數值劃分區間參數），而比 5 小的值是 3.5，因此 3.5 與 5 為一個區間；第二次取出第二個參數中的 C3（即 3），同樣在 C2:C7 中統計小于等于 3 且大于 2.5 的數值個數（結果為 1）；第三次取出 5，由于 5 已經統計過不再計入統計，因此結果為 0；其它的以此類推，最后返回數組 {2;1;0;1;1;1;0}。

　　B、則 0/(FREQUENCY(C2:C7,C2:C7) 變為 0/{2;1;0;1;1;1;0}，接著用 0 除以數組中的每個數，結果為 {0;0;#DIV/0!;0;0;0;#DIV/0!}；用 0 除以數組中的每個值主要是把數組中的 0 過濾掉，即把統計過的和沒有的值過濾掉。

　　C、則公式變為 =COUNT({0;0;#DIV/0!;0;0;0;#DIV/0!})，最后對數組中的數值進行統計，總共有 5 個 0，兩個除數為 0 錯誤 #DIV/0!，因此統計結果為 5。